@echo off
if %PC%==error goto end
if "%1"=="" goto usage
if NOT "%1"=="/copy" goto s0
shift
goto copying
:s0
if "%2"=="" goto usage
if "%3"=="" goto usage
rem ***************************************************************************
rem  You must have also following zips (check names):
rem  fontcm.zip, fontltx.zip, fontemsy.zip, fontams.zip (Fonts)
rem  makeindx.zip, texcad.zip, pictex.zip (additional packages)
rem
rem  PART ONE:  MAIN emTeX
rem  Please correct this column only:
rem                      vvvvvvvv
rem Main part:
if "%3"=="frst" %0 %1 %2 first    %4 %5 %6 %7 %8 %9
if "%3"=="texp" %0 %1 %2 tex4b    %4 %5 %6 %7 %8 %9
if "%3"=="emrs" %0 %1 %2 emxrsx   %4 %5 %6 %7 %8 %9
if "%3"=="done" %0 %1 %2 dvid16g1 %4 %5 %6 %7 %8 %9
if "%3"=="dtwo" %0 %1 %2 dvid16g2 %4 %5 %6 %7 %8 %9
if "%3"=="mfpr" %0 %1 %2 mf4b     %4 %5 %6 %7 %8 %9
if "%3"=="mfjp" %0 %1 %2 mfjob12d %4 %5 %6 %7 %8 %9
if "%3"=="ltxo" %0 %1 %2 latex209 %4 %5 %6 %7 %8 %9
if "%3"=="ltxi" %0 %1 %2 l2input  %4 %5 %6 %7 %8 %9
if "%3"=="tedt" %0 %1 %2 texedt   %4 %5 %6 %7 %8 %9
if "%3"=="tool" %0 %1 %2 l2toolx  %4 %5 %6 %7 %8 %9
rem Other packages:
if "%3"=="psex" %0 %1 %2 dvipsexe %4 %5 %6 %7 %8 %9
if "%3"=="bibt" %0 %1 %2 bibtex4b %4 %5 %6 %7 %8 %9
rem ***************************************************************************
rem  PART TWO: Cyrtug-emTeX98 archives:
rem  Don't change lines below:
if "%3"=="amst" %0 %1 %2 amstex1  %4 %5 %6 %7 %8 %9
if "%3"=="babl" %0 %1 %2 babel36  %4 %5 %6 %7 %8 %9
if "%3"=="nfss" %0 %1 %2 nfss1    %4 %5 %6 %7 %8 %9
if "%3"=="mitt" %0 %1 %2 l209tool %4 %5 %6 %7 %8 %9
rem Archives with russification:
if "%3"=="cyrt" %0 %1 %2 lhpck32f %4 %5 %6 %7 %8 %9
if "%3"=="lhfn" %0 %1 %2 lhpck32f %4 %5 %6 %7 %8 %9
rem ***************************************************************************

:chck
for %%c in (A,B,a,b) do if %%c==%2 goto ch2
if exist %2:%3.zip goto unp
if exist %3.zip goto zp
goto zq
:ch2
echo Insert diskette with file %3.zip
pause
if NOT exist %2:%3.zip goto zq
:unp
echo        %3.zip ...
%eminst%\pkunzip %2:%3 %4 %5 %6 %7 %8 %9>%eminst%\%3.log
if errorlevel 1 goto nofile
goto end
:zp
echo        %3.zip ...
%eminst%\pkunzip %3 %4 %5 %6 %7 %8 %9>%eminst%\%3.log
if errorlevel 1 goto nofile
goto end

:zq
echo.
echo Zip file %3.zip absent in current diskette/directory.
echo Do you have it in directory/(another) diskette ?
echo Type floppy disk name -- A or B
echo Repeat attempt        -- R
echo Skip this file        -- S
echo Quit installation     -- Q
%eminst%\ask.exe Press letter (A/B/R/S/Q),aAbBSsRrqQ
echo.
if errorlevel 9 goto nofile
if errorlevel 7 goto chck
if errorlevel 5 goto end
if errorlevel 3 goto db
:da
echo.
echo Insert diskette with file %3.zip in drive A
pause
if exist a:%3.zip goto da0
%eminst%\ask.exe Do you really have %3.zip on diskette A ? (Y/N) Insert necessary diskette.,yYnN
echo.
if errorlevel 3 goto zq
goto da
:da0
echo        %3.zip ...
%eminst%\pkunzip a:%3 %4 %5 %6 %7 %8 %9>nul
if errorlevel 1 goto nofile
goto end
:db
echo.
echo Insert diskette with file %3.zip in drive B
pause
if exist b:%3.zip goto db0
%eminst%\ask.exe Do you really have %3.zip on diskette B ? (Y/N) Insert necessary diskette.,yYnN
echo.
if errorlevel 3 goto zq
goto db
:db0
echo        %3.zip ...
%eminst%\pkunzip b:%3 %4 %5 %6 %7 %8 %9>nul
if errorlevel 1 goto nofile
goto end

:copying
if NOT exist %dvidrvfonts%\%4 goto fl1
%eminst%\ask.exe Font library %4 already exists. Overwrite ? (Y/N),YyNn
echo.
if errorlevel 3 goto end
:fl1
for %%c in (A,B,a,b) do if %%c==%2 goto fl2
if exist %2:%3 goto fl10
if exist %3 goto fl20
goto fl3
:fl2
echo Insert diskette with file %3
pause
if NOT exist %2:%3 goto fl3
:fl10
echo Copy %3 to %dvidrvfonts%\%4
copy %2:%3 %dvidrvfonts%\%4>nul
goto end
:fl20
echo Copy %3 to %dvidrvfonts%\%4
copy %3 %dvidrvfonts%\%4>nul
goto end
:fl3
echo File %3 absent in current diskette/directory.
echo Do you have it in directory/(another) diskette ?
echo Type floppy disk name -- A or B
echo Repeat attempt        -- R
echo Skip this file        -- S
%eminst%\ask.exe Press letter (A/B/R/S),aAbBRrSs
echo.
if errorlevel 7 goto end
if errorlevel 5 goto fl1
if errorlevel 3 goto fb
:fa
echo.
echo Insert diskette with file %3 in drive A
pause
if exist a:%3 goto fa0
%eminst%\ask.exe Do you really have %3 on diskette A ? (Y/N),yYnN
echo.
if errorlevel 3 goto fl3
:fa0
echo Copy %3 to %dvidrvfonts%\%4
copy a:%3 %dvidrvfonts%\%4>nul
if errorlevel 1 goto nofile
goto end
:fb
echo.
echo Insert diskette with file %3 in drive B
pause
if exist b:%3 goto fb0
%eminst%\ask.exe Do you really have %3 on diskette B ? (Y/N),yYnN
echo.
if errorlevel 3 goto fl3
:fb0
echo Copy %3 to %dvidrvfonts%\%4
copy b:%3 %dvidrvfonts%\%4>nul
if errorlevel 1 goto nofile
goto end

:usage
echo This file is satellite to install98.bat and cinst98.bat
goto end
:nofile
echo.
echo ERROR see log-files in %eminst%
set PC=error
:end
