/***************************************************************************/
//		horizon.pov
//		by Hero Ngauv
/***************************************************************************/

#include "colors.inc"
#include "textures.inc"
#include "herotxtr.inc"
//#include "shapes.inc"

#declare Vector = <-30,20,-100>
#declare Direction = 1
camera{
  location Vector
  sky <-1,0,0>		//to turn the camera on its side
  direction <0,0,Direction>
  up <0,1*(2/3),0>
  right <4/3*(2/3),0,0>
  look_at <-40,0,0>
}
light_source{ (Vector + <0,0,0>) color Gray15 }	//this will partially
						//light up the scene from
						//behind

light_source{ <-250,-250,700> color rgb <1.5,1.5,1.5> }	//these will
plane{ <0,-0.065,1>, 0					//simulate the
  texture{						//sun with specular
    pigment{ color Clear }				//highlights
    finish{ specular 0.5 roughness 0.05 }
  }
  translate <0,0,950>
}

light_source{ <-1000,-150,1000> color rgb <2,2,2> }
						/*this actually light up the
						planet and moon*/
/***************************************************************************/
sphere{ <0,0,0>, 50			//the cloud layer
  texture{
    Cloud_Texture
    finish{ diffuse 0.8 ambient 0.05 }
    turbulence 1
    scale <80,25,80>
    translate <0,5,0>
    rotate <0,-135,15>
  }
}
sphere{ <0,0,0>, 49			//the planet
  texture{
    Planet_Texture
    finish{ ambient 0.05 }
    turbulence 0.75
    scale 35
    rotate <0,30,0>
  }
}
sphere{ <-17,0,-50>, 12			//the moon
  texture{
    pigment{ Gray50 }
    finish{ brilliance 1 ambient 0.05 }
    normal{ wrinkles 2 }
    turbulence 1
    scale 2
  }
}
/***************************************************************************/
plane{ <0,0,1>, 10000			//the night sky
  texture{
    pigment{
      image_map{ gif "fract005.gif" }
    }
    finish{ ambient 1 diffuse 0 }
    scale 10000
  }
}