// ************************************************************************************************************************
// Brothel (Joined HFs) - Creates Brothel_Object
// ************************************************************************************************************************
#macro Make_Brothel ()
   #declare Thickness = 0.03;
   union {
      // Front Wall
      height_field {jpeg "_Bro_02a.jpg" smooth water_level 1/255
         scale <1,Thickness,1> rotate x*-90
         #if (Images_On)
            pigment {image_map {jpeg "_Bro_02b.jpg" interpolate 2.0 map_type 0} }
         #else
            pigment {color (Green+White)/2}
         #end
         finish {ambient 0.30 crand 0.15}
         translate z*Thickness
         #if (Normals_On=1) normal {granite 0.6 scale 0.2 accuracy 1e-9} #end
         }
      // Left Wall
      height_field {jpeg "_Bro_01a.jpg" smooth water_level 16/255
         scale <1,-Thickness,1> rotate x*-90 rotate y*-90 
         #if (Images_On)
            pigment {image_map {jpeg "_Bro_01b.jpg" interpolate 2.0 map_type 0} rotate y*90}
         #else
            pigment {color (Green+White)/2}
         #end
         finish {ambient 0.26 crand 0.15}
         #if (Normals_On=1) normal {granite 0.6 scale 0.2 accuracy 1e-9} #end
         }
      // Right Wall
      height_field {jpeg "_Bro_01a.jpg" smooth water_level 16/255 
         scale <1,-Thickness,1> rotate x*-90 rotate y*-90 translate x*1.0
         // pigment {Orange*0.6} finish {ambient 0.3}
         #if (Images_On)
            pigment {image_map {jpeg "_Bro_01b.jpg" interpolate 2.0 map_type 0} rotate y*-90}
         #else
            pigment {color (Green+White)/2}
         #end
         finish {ambient 0.26 crand 0.15}
         #if (Normals_On=1) normal {granite 0.6 scale 0.2 accuracy 1e-9} #end
         }
      // Back Wall
      height_field {jpeg "_Bro_03a.jpg" smooth water_level 16/255
         scale <1,Thickness,1> rotate x*-90 translate z*1 translate z*-Thickness
         #if (Images_On)
            pigment {image_map {jpeg "_Bro_03b.jpg" interpolate 2.0 map_type 0} }
         #else
            pigment {color (Green+White)/2}
         #end
         finish {ambient 0.22 crand 0.15}
         #if (Normals_On=1) normal {granite 0.6 scale 0.2 accuracy 1e-9} #end
         }
      // *********************************************************************************************************************
      // First Floor Debris
      height_field {jpeg "_Bro_04.jpg" smooth water_level 127/255 
         scale <1.2,Thickness,1.2> translate <-0.1,0,-0.1>
         // pigment {Brown*0.9} finish {ambient 0.3}
         #if (Images_On)
            pigment {image_map {jpeg "_Bro_04.jpg" interpolate 2.0 map_type 0} rotate x*90 scale 0.1 turbulence 0.6}
         #else
            pigment {color Yellow*0.25}
         #end
         finish {ambient 0.30 crand 0.15}
         normal {granite 2.0 scale 0.02 accuracy 1e-9}
         }
      // *********************************************************************************************************************
   }
#end

